From: rickNOSPAMnews@NOSPAMcomcast.net   
      
   > Thank you very much Rick for the usefull reply. But i'v got another   
   > question. When drawing the line, you cant see the line untill you   
   > release the mouse button. I want to see the line when im drawing!!   
   > Im using the following code:   
   >   
   > Private Sub Picture1_MouseDown(Button As Integer, Shift As Integer, X   
   > As Single, Y As Single)   
   >      x1 = z.X   
   >     y1 = z.Y   
   >     ............   
      
   I couldn't run your code because I don't know what "z" is (although it   
   apparently has an X and Y property). Anyway, below is some code that   
   will show the line as you draw it. It uses a Line control that is IN the   
   PictureBox (use one of the two previously methods I posted to place it   
   inside). You can copy/paste it exactly as is, although note that I used   
   line continuations for the Sub's event declarations in order to avoid   
   long line wrapping in your newsreader (you can change them back to   
   single lines if you wish).   
      
   Rick - MVP   
      
   Dim LineIsActive As Boolean   
      
   Private Sub Picture1_MouseDown(Button As Integer, _   
               Shift As Integer, X As Single, Y As Single)   
     With Line1   
       If Not .Visible Then .Visible = True   
       LineIsActive = True   
       .X1 = X   
       .Y1 = Y   
       .X2 = X   
       .Y2 = Y   
     End With   
   End Sub   
      
   Private Sub Picture1_MouseMove(Button As Integer, _   
               Shift As Integer, X As Single, Y As Single)   
     If LineIsActive Then   
       With Line1   
         .X2 = X   
         .Y2 = Y   
       End With   
     End If   
   End Sub   
      
   Private Sub Picture1_MouseUp(Button As Integer, _   
               Shift As Integer, X As Single, Y As Single)   
     LineIsActive = False   
     With Line1   
       .X2 = X   
       .Y2 = Y   
     End With   
   End Sub   
      
   --- SoupGate-Win32 v1.05   
    * Origin: you cannot sedate... all the things you hate (1:229/2)