From: marianjones@helpfulpeople.com   
      
   Marian wrote:   
   > What can we do so as to get the "real" full possible output every time?   
      
   This is basic code that will put our AP scan result into a log file.   
      
    @echo off   
    REM This is netscan.bat version 1p0   
    REM v1p0 202512132 outputs wifi adapter AP cache to a log file   
    set "logdir=C:\data\sys\log"   
    if not exist "%logdir%" mkdir "%logdir%"   
      
    for /f %%A in ('wmic os get localdatetime ^| find "."') do set dt=%%A   
    set "ts=%dt:~0,8%_%dt:~8,6%"   
    set "logfile=%logdir%\wifiscan_test_%ts%.log"   
      
    echo === Wi-Fi scan at %date% %time% === >> "%logfile%"   
    netsh wlan show networks mode=bssid >> "%logfile%"   
    echo --- End of scan --- >> "%logfile%"   
      
    echo Log written to %logfile%   
    pause   
      
   The problem is that the running of that script at different times gets   
   different answers, but we want the "fullest" answer Windows can give us.   
      
   A 'netsh wlan show networks mode=bssid' scan will contain the most access   
   points when the wireless adapter has had time to complete a fresh   
   background scan cycle, typically 10¡V30 seconds after disconnecting or   
   reconnecting, and especially when the adapter is not actively passing   
   traffic.   
      
     @echo off   
     REM This is netscan.bat version 1p1   
     REM Without admin, we can only work with known Wi-Fi profiles   
     REM v1p0 20251213 outputs wifi adapter AP cache to a log file   
     REM v1p1 20251213 disconnects/reconnects Wi-Fi, then outputs AP cache   
      
     set ssid=your_ssid_nomap   
      
     REM Disconnect from any current SSID (no admin required)   
     echo [%date% %time%] Disconnecting Wi-Fi...   
     netsh wlan disconnect   
     timeout /t 10 >nul   
      
     REM Reconnect to the specified SSID   
     echo [%date% %time%] Connecting to %ssid%...   
     netsh wlan connect name=%ssid%   
     timeout /t 15 >nul   
      
     REM Prepare log file   
     set "logdir=C:\data\sys\log"   
     if not exist "%logdir%" mkdir "%logdir%"   
      
     for /f %%A in ('wmic os get localdatetime ^| find "."') do set dt=%%A   
     set "ts=%dt:~0,8%_%dt:~8,6%"   
     set "logfile=%logdir%\wifiscan_%ts%.log"   
      
     REM Write scan results (fullest possible AP list)   
     echo === Wi-Fi scan at %date% %time% === >> "%logfile%"   
     netsh wlan show networks mode=bssid >> "%logfile%"   
     echo --- End of scan --- >> "%logfile%"   
      
     echo Log written to %logfile%   
     pause   
      
   This will get us a much larger (fuller) list of available AP's nearby.   
   But more has to be done to get it to be the "fullest" list possible.   
   --   
   I go to trouble and time and effort to write my Usenet posts because I'm   
   kind hearted enough to care that everyone gets excellent researched data.   
      
   --- SoupGate-Win32 v1.05   
    * Origin: you cannot sedate... all the things you hate (1:229/2)