From: marianjones@helpfulpeople.com   
      
   Marian wrote:   
   > This will get us a much larger (fuller) list of available AP's nearby.   
   > But more has to be done to get it to be the "fullest" list possible.   
      
   Below, I added a few delays to see how many more APs would be found.   
   It found about a score of APs, but with different amounts in each scan.   
      
    @echo off   
    REM This is netscan.bat version 1p2   
    REM Without admin, we can only work with known Wi-Fi profiles   
    REM v1p0 20251213 outputs wifi adapter AP cache to a log file   
    REM v1p1 20251213 disconnects/reconnects Wi-Fi, then outputs AP cache   
    REM v1p2 20251213 captures multiple snapshots for the fullest AP list   
      
    set ssid=starbucks.office_nomap   
    set "logdir=C:\data\sys\log"   
    if not exist "%logdir%" mkdir "%logdir%"   
      
    for /f %%A in ('wmic os get localdatetime ^| find "."') do set dt=%%A   
    set "ts=%dt:~0,8%_%dt:~8,6%"   
    set "logfile=%logdir%\wifiscan_%ts%.log"   
      
    echo === Wi-Fi scan session started at %date% %time% === >> "%logfile%"   
      
    REM 1) Disconnect from current SSID   
    echo [%date% %time%] Disconnecting Wi-Fi...   
    netsh wlan disconnect   
    timeout /t 12 >nul   
      
    echo [%date% %time%] Scan A (disconnected state)...   
    netsh wlan show networks mode=bssid >> "%logfile%"   
    echo --- End of Scan A --- >> "%logfile%"   
      
    REM 2) Reconnect to target SSID   
    echo [%date% %time%] Reconnecting to %ssid%...   
    netsh wlan connect name=%ssid%   
    timeout /t 15 >nul   
      
    echo [%date% %time%] Scan B (after reconnect)...   
    netsh wlan show networks mode=bssid >> "%logfile%"   
    echo --- End of Scan B --- >> "%logfile%"   
      
    REM 3) Wait longer for background scan to complete   
    timeout /t 20 >nul   
    echo [%date% %time%] Scan C (delayed snapshot)...   
    netsh wlan show networks mode=bssid >> "%logfile%"   
    echo --- End of Scan C --- >> "%logfile%"   
      
    echo === Wi-Fi scan session finished at %date% %time% === >> "%logfile%"   
    echo Log written to %logfile%   
    pause   
      
   --   
   Part of the reason I document in detail is for others to benefit who don't   
   even use Usenet since my threads are often the first hits on Google search.   
      
   --- SoupGate-Win32 v1.05   
    * Origin: you cannot sedate... all the things you hate (1:229/2)