XPost: alt.comp.software.firefox   
   From: marion@facts.com   
      
   UPDATE:   
      
   Since we're layering free no-registration VPNs onto open source proxies   
   onto free no-registration proxifiers onto free no-registration privacy   
   extensions, it behooves us to be able to check proxy settings dynamically.   
      
   I never messed with proxies before, but darn'it, Windows splatters proxy   
   settings all over the place, such that I needed a quick testing script.   
      
   Below is a script which simplifies visibility and control over what turns   
   out to be a devilishly fragmented system of how Windows defines proxies.   
    a. WinINET: Used by Internet Explorer, Chrome, and many apps;   
    b. WinHTTP: Used by system services and background tasks;   
    c. PAC/AutoDetect: Dynamic proxy configuration via commands.   
      
   Unfortunately, I've run into this proxy setup complexity due to using   
    A. VPN, which encrypts traffic and changes routing;   
    B. Psiphon, which tunnels & encrypts SOCKS5 & HTTPS traffic;   
    C. FreeCap, which redirects app traffic through SOCKS proxies.   
      
   The proxy.bat script included below checks all three methods at once   
   which gives us a clear snapshot of what the Windows proxy setup is.   
      
   To that end, we add a new command to run in your Win+R taskbar Runbox:   
     Win+R/Runbox > proxy   
   Which executes this added registry "App Paths" key:   
     HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\proxy.exe   
   Which runs this proxy checking tool (see the tool below in its entirety):   
     C:\sys\bat\proxy.bat   
      
    ===< cut here for proxy.bat >===   
    @echo off   
    REM proxy.bat 20250820 v1.0 ¡X Unified Windows check-proxy diagnostic tool   
    REM Reports: WinINET manual proxy, WinHTTP proxy, PAC/AutoDetect   
    REM 20250820 rev 1.0   
    REM HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\proxy.exe   
    REM Default=C:\sys\bat\proxy.bat ==> creates "Win+R > proxy" command   
    setlocal   
      
    set KEY="HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings"   
      
    echo ==============================================   
    echo   WINDOWS PROXY CONFIGURATION CHECK   
    echo ==============================================   
      
    REM --- WinINET (manual proxy) ---   
    echo.   
    echo [1] WinINET / Internet Settings   
    for /f "tokens=2,* skip=2" %%A in ('reg query %KEY% /v ProxyEnable 2^>nul')   
   do set ProxyEnable=%%B   
    for /f "tokens=2,* skip=2" %%A in ('reg query %KEY% /v ProxyServer 2^>nul')   
   do set ProxyServer=%%B   
    if "%ProxyEnable%"=="0x1" (   
        echo Proxy is ENABLED   
        echo Proxy server: %ProxyServer%   
    ) else (   
        echo Proxy is DISABLED   
    )   
      
    REM --- WinHTTP proxy ---   
    echo.   
    echo [2] WinHTTP proxy (system/background services)   
    netsh winhttp show proxy   
      
    REM --- PAC (Proxy Auto-Config) & AutoDetect ---   
    echo.   
    echo [3] PAC / AutoDetect   
    for /f "tokens=2,* skip=2" %%A in ('reg query %KEY% /v AutoConfigURL 2^>nul')   
   do set PACurl=%%B   
    for /f "tokens=2,* skip=2" %%A in ('reg query %KEY% /v AutoDetect 2^>nul') do   
   set AutoDetect=%%B   
      
    if defined PACurl (   
        echo PAC script set: %PACurl%   
    ) else (   
        echo No PAC script URL found.   
    )   
      
    if "%AutoDetect%"=="0x1" (   
        echo Auto-detect is ENABLED   
    ) else (   
        echo Auto-detect is DISABLED   
    )   
      
    echo.   
    echo ==============================================   
    echo Check complete.   
    echo ==============================================   
      
    endlocal   
    pause   
    ===< cut here for proxy.bat >===   
      
   As always, this is posted to help others copy & paste   
   (where wasbit's kind and helpful advice is appreciated)   
   this script as part of their addition of privacy to Windows.   
      
   --- SoupGate-Win32 v1.05   
    * Origin: you cannot sedate... all the things you hate (1:229/2)