XPost: alt.comp.freeware   
   From: marion@facts.com   
      
   It's not easy finding a free no-registration Windows proxifier, but I've   
   been testing these two recently and they work to proxify almost any app.   
       
       
    Name: apponic_freecap_setup_eng.exe   
    Size: 1644848 bytes (1606 KiB)   
    SHA256: C3D4929AB5A5867A6BE9914FF94DEFEFED6762748EDB1E351C86EBC5A02D46EC   
      
       
       
    Name: informer_freecap_setup_eng.exe   
    Size: 1644848 bytes (1606 KiB)   
    SHA256: C3D4929AB5A5867A6BE9914FF94DEFEFED6762748EDB1E351C86EBC5A02D46EC   
      
       
       
    Name: SocksCap64-setup-3.6.exe   
    Size: 6193115 bytes (6047 KiB)   
    SHA256: B2DA49EC9A2702CFD7625D3F152AF98A4C8E3E155DAB78686962BB3DF1F76825   
      
   I used FreeCap for a few weeks until I switched over to the slightly more   
   modern & functional SocksCap64 tool to proxify apps w/o proxy capabilities.   
      
   In general, you'll need a proxy first, which Psiphon3 does for you:   
       
       
    Name: psiphon3.exe   
    Size: 10402576 bytes (10158 KiB)   
    SHA256: DB1BAF76F0333F4743919A86F35037559F9E7DA7DF14982DFC16FB8DC0BE6BE2   
      
   Install location C:\apps\network\proxy\{psiphon,sockscap,freecap}\   
   Software archives C:\software\network\proxy\{psiphon,sockscap,freecap}\   
   Pullout menu C:\menus\network\proxy\{psiphon,sockscap,freecap}\   
      
   While we're at it, the following script helps both to report and to   
   sync Psiphon settings inside of Windows for apps that have proxy GUIs.   
     ==< cut here for proxy.bat >==   
    @echo off   
    REM proxy.bat 20250820 v1.2   
    REM Use model: "Win+R > proxy" (proxy import if WinHTTP is unset)   
    REM Unified Windows proxy diagnostic tool with WinHTTP sync safeguard   
    REM "Win+R > proxy /sync imports WinINET proxy directly into WinHTTP   
    REM Reports: WinINET manual proxy, WinHTTP proxy, PAC/AutoDetect   
    REM HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\proxy.exe   
    REM Default=C:\sys\batch\proxy.bat   
    REM That App Paths key creates the convenient "Win+R > proxy" command   
    REM   
    setlocal   
      
    :: --- Quick /sync mode ---   
    if /i "%~1"=="/sync" (   
        echo Syncing WinINET proxy into WinHTTP...   
        netsh winhttp import proxy source=ie   
        echo Done.   
        pause   
        exit /b   
    )   
      
    set KEY="HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings"   
      
    echo ==============================================   
    echo   WINDOWS PROXY CONFIGURATION SET/CHECK/FIX   
    echo ==============================================   
      
    REM --- WinINET (manual proxy) ---   
    echo.   
    echo [1] WinINET / Internet Settings   
    for /f "tokens=2,* skip=2" %%A in ('reg query %KEY% /v ProxyEnable 2^>nul')   
   do set ProxyEnable=%%B   
    for /f "tokens=2,* skip=2" %%A in ('reg query %KEY% /v ProxyServer 2^>nul')   
   do set ProxyServer=%%B   
    if "%ProxyEnable%"=="0x1" (   
        echo Proxy is ENABLED   
        echo Proxy server: %ProxyServer%   
    ) else (   
        echo Proxy is DISABLED   
    )   
      
    REM --- WinHTTP proxy ---   
    echo.   
    echo [2] WinHTTP proxy (system/background services)   
      
    REM Get current WinHTTP proxy setting   
    for /f "tokens=1,* delims=:" %%A in ('netsh winhttp show proxy ^| findstr /R   
   /C:"Proxy Server(s)"') do set curWinHTTP=%%B   
      
    REM Trim leading/trailing spaces   
    set curWinHTTP=%curWinHTTP:~1%   
      
    if "%curWinHTTP%"=="" (   
        echo No WinHTTP proxy set - importing from WinINET...   
        netsh winhttp import proxy source=ie >nul 2>&1   
    ) else (   
        echo WinHTTP proxy already set - leaving as is.   
    )   
      
    REM Show current WinHTTP proxy after check/import   
    netsh winhttp show proxy   
      
    REM --- PAC (Proxy Auto-Config) & AutoDetect ---   
    echo.   
    echo [3] PAC / AutoDetect   
    for /f "tokens=2,* skip=2" %%A in ('reg query %KEY% /v AutoConfigURL 2^>nul')   
   do set PACurl=%%B   
    for /f "tokens=2,* skip=2" %%A in ('reg query %KEY% /v AutoDetect 2^>nul') do   
   set AutoDetect=%%B   
      
    if defined PACurl (   
        echo PAC script set: %PACurl%   
    ) else (   
        echo No PAC script URL found.   
    )   
      
    if "%AutoDetect%"=="0x1" (   
        echo Auto-detect is ENABLED   
    ) else (   
        echo Auto-detect is DISABLED   
    )   
      
    echo.   
    echo ==============================================   
    echo Windows proxy set/check/fix complete.   
    echo ==============================================   
      
    endlocal   
    pause   
      
     ==< cut here for proxy.bat >==   
      
   --- SoupGate-Win32 v1.05   
    * Origin: you cannot sedate... all the things you hate (1:229/2)